Теанин (L-Theanine) – Умный кофе — Smart Caffeine

Теанин (L-Theanine) – Умный кофе — Smart Caffeine

Самое главное с утра, после умывания и опорожнения кишечника 🙂 является чашечка хорошего и вкусного кофе, а если мы его сделаем еще более полезным и эффективным, то считайте, что день у вас пройдет с зарядом положительных эмоций и морем энергии для созидания или разрушения, кому как нравится 😉

Небольшое лирическое отступление, процесс создания сублимированного кофе убивает его настоящий и прекрасный вкус, просто возьмите френч-пресс, измельчите зерна и приготовьте настоящий кофе! Но предупреждаю, после этого вы вряд ли сможете, так же как и раньше наслаждаться растворимым кофе. Добро пожаловать в ряды ценителей настоящего кофе!

В приготовлении, так называемого «Умного кофе» или «smart caffeine», нам поможет «L-Theanine (Теанин)», который, по сути, является аминокислотой полученной из листьев зеленого чая и является синергетической добавкой к кофе, усиливающий его положительные свойства и смягчающий негативные, при этом добавляя собственные полезные эффекты, например, борьба со стрессовыми состояниями, улучшение работы мозга за счет повышения альфа-ритма, а так же улучшение качества сна.

В продаже имеются уже готовые капсулы «smart caffeine», в составе которых обычно 100 мг кофеина и 200 мг «L-Theanine (Теанин)». Эффективно? Да! Но при их использовании мы не получаем другие полезные вещества из зерен кофе, которые так же необходимы. Рекомендую данные капсулы носить с собой и использовать их, когда это необходимо, собственно так я и поступаю.

Ну что же, приступим, все очень просто:

  1. Завариваем кофе:
    Завариваем кофе - «L-Theanine (Теанин)»

    Завариваем кофе — «L-Theanine (Теанин)»

  2. Растворяем «L-Theanine (Теанин)»:
    Растворяем «L-Theanine (Теанин)»

    Растворяем «L-Theanine (Теанин)»

  3. Наслаждаемся «умным кофе»:
    Наслаждаемся «умным кофе» - Теанин (L-Theanine) – Умный кофе - Smart Caffeine

    Наслаждаемся «умным кофе»

Эффект не заставить себя ждать, вы более сконцентрированы, более спокойны и соответственно более эффективны. Дополнительно, для более сильного эффекта можно добавить, женьшень, немного корицы и закусить кусочком горького шоколада 😉

Дополнительный материал:

  1. Теанин (L-Theanine)
  2. L-Теанин: Внимание к Деталям
  3. Theanine — From Wikipedia, the free encyclopedia

P.S. Не злоупотребляйте!

С Новым 2018 годом!

С Новым 2018 годом!  🙂 Желаю в год желтой собаки всего самого простого: от близких — любви и понимания, на работе — больших премий и растущих зарплат, а для душевного равновесия — как можно больше приятных мелочей и достижимых целей  😎 ©

Тестирование 1С:Профессионал по технологическим вопросам

Тестирование 1С:Профессионал по технологическим вопросам

В настоящее время веду самостоятельную подготовку к сдаче аттестации «1С:Эксперт по технологическим вопросам» и первым небольшим шагом является сдача тестирования «1С:Профессионал по технологическим вопросам», что недавно и произошло.

Основными источниками информации, для подготовки являются:

Курсы:

Сайты для подготовки к «Тестирование 1С:Профессионал по технологическим вопросам»:

Успешной сдачи!  😉

Обновлено 01.12.2017: А вот и результат, успешная сдача аттестации 1С:Эксперт по технологическим вопросам:

1С:Эксперт по технологическим вопросам

1С:Эксперт по технологическим вопросам

Персональный информационный менеджер

Personal Information Manager — Персональный информационный менеджер

Материал из Википедии — свободной энциклопедии:

Персональный информационный менеджер, ПИМ (англ. Personal Information Manager, PIM) — компьютерная программа, служащая для облегчения работы с разного рода личной информацией. В простейшем случае это программа, выполняющая функции персонального органайзера. Более сложные программы имеют дополнительные функции, позволяющие вести совместное планирование и организовывать совместную работу над проектами (Groupware).

В свое время, озадачился хранением разнородной информации консолидировано, было перепробовано много различных программ от простых wiki систем до облачных решений, но все так или иначе имели свои недостатки и ограничения. Некоторые не позволяли оформлять текст, добавлять большие файлы или имели не удобную структуру и зависели от подключения к интернету.

Оптимальное решение было найдено, программа EssentialPIM — в бесплатной версии имеется весь необходимый функционал, при том что использую лишь опцию «Заметки». Данные хранятся в локальном файле с расширением «.epim», который легко можно синхронизировать с другими компьютерами при помощи того же Яндекс.Диск или Google Drive. При помощи тех же сервисов можно хранить файлы, ссылки на которые добавлять в текст заметки, при этом нас ограничивают лишь размеры жесткого диска и если необходима синхронизация, то размер «облака».

Пример, как выглядит домашняя база, в которой не особо много данных:

Essentialpim-1 Personal Information Manager - Персональный информационный менеджер

Essentialpim-1 Personal Information Manager — Персональный информационный менеджер

Особенности программы

Сама по себе программа имеет обширный функционал, который в последующем так же можно использовать в повседневной работе. Особенности программы: Сегодня — Полный обзор предстоящих дел в простом и понятном виде. Здесь собраны данные со всех модулей, которые дают обзор ближайших и будущих дел. Календарь — Красочные, легкие для чтения и понимания дневной, недельный, месячный и годовой виды. Дела — Гибкое структурирование дел с использованием иерархии и закладок. Возможность фильтрации данных. Заметки — Плоская или иерархическая структура заметок. Или их комбинация. Контакты — Многоуровневость групп и мощные фильтры гарантируют легкое нахождение контакта. Почта — Переносная версия для USB-флешки, способная работать как в онлайн так и оффлайн режиме. Пароли — Удобный способ хранить все ваши пароли и другую конфиденциальную информацию. Корзина — Гарантирует сохранность ваших данных от случайного удаления.

http://www.essentialpim.com/images/essentialpim_2016_may/slide-5.png

Разработка мобильных приложений 1С

Разработка мобильных приложений 1С – Быстрый старт!

В этой небольшой статье, которая является началом цикла «Разработка мобильных приложений 1С», покажу, как можно быстро создать 1С мобильное приложение «Привет мир», на основе мобильной платформы 1С.

Для тестирования готового мобильного приложения 1С, будет использоваться реальное устройство на основе операционной системы Android, с использованием мобильной платформы для разработчиков и возможности отладки по протоколу HTTP.
Читать далее

Начисление амортизации в рамках срока полезного использования

Начисление амортизации в рамках срока полезного использования.

Делюсь реализацией задачи о начислении амортизации основного средства в пределах периода срока полезного использования. Необходимо доработать типовой функционал конфигурации «Управление производственным предприятием», редакция 1.3, для того чтобы, при проведении документа «Амортизация ОС», анализировался срок полезного использования основного средства и производилось начисление амортизации в рамках срока полезного использования. Так как, иногда возникали ситуации, когда срок полезного использования завершен, а начисление производилось в последующие месяцы и обычно это были не большие суммы.
Схематично ситуацию можно представить следующим образом:

Начисление амортизации в рамках срока полезного использования

Начисление амортизации в рамках срока полезного использования


Доработка реализована для управленческого, бухгалтерского и налогового учета, основных средств, использующих линейных метод начисления.
При анализе кода проведения документа «Амортизация ОС», основные расчеты суммы начисления амортизации, производятся в общем модуле «УправлениеВнеоборотнымиАктивами», в соответствующих функциях: «РасчетАмортизацииУпр», «РасчетАмортизацииБухРегл» и «РасчетАмортизацииНалогРегл». Указанные функции по своей структуре схожи и имеют в своем составе основной запрос и последующий расчет начисления суммы амортизации.
Читать далее

1С СКД: Суммирование значений на различных уровнях группировок

1С СКД: Суммирование значений на различных уровнях группировок

В данной небольшой заметке хочу показать, как можно произвести суммирование значений на различных уровнях группировки, в отчете с использованием системы компоновки данными.
Как показано на изображении, только на уровне группировки «Группы номенклатуры», рассчитывается ресурс «Заказать», в нем отображается, сколько нужно заказать по текущей группе номенклатуры исходя из определенных условий:

1С СКД: Суммирование значений на различных уровнях группировок

1С СКД: Суммирование значений на различных уровнях группировок


Данное значение может быть рассчитано только на данном уровне группировки, так как, выше или ниже, отсутствуют значения для расчета. Например, на уровне детальных записей, нет данных по максимальному количеству в группе, потому что эти данные верны только для группы в целом, а не для отдельных ее составляющих.

Соответственно, теперь необходимо рассчитать итоги, по выше находящимся группировкам («Склады», «ТипыСкладов») и общий итог.
Для этого используется функция ВычислитьВыражениеСГруппировкойМассив:
ВЫЧИСЛИТЬВЫРАЖЕНИЕСГРУППИРОВКОЙМАССИВ (EVALEXPRESSIONWITHGROUPARRAY)
Синтаксис:
ВычислитьВыражениеСГруппировкойМассив(<Выражение>, <ВыражениеПолейГруппировки>, <ОтборЗаписей>, <ОтборГруппировок>)
Описание:
Функция возвращает массив, каждый элемент которого содержит результат вычисления выражения для группировки по указанному полю.
Компоновщик макета при генерации макета преобразовывает параметры функции в термины полей макета компоновки данных. Например, поле Контрагент будет преобразовано в НаборДанных.Контрагент.
Компоновщик макета при генерации выражений для вывода пользовательского поля, в выражении которого присутствует только функцияВычислитьМассивСГруппировкойМассив(), генерирует выводимое выражение таким образом, чтобы выводимая информация была упорядочена. Например, для пользовательского поля с выражением:

ВычислитьВыражениеСГруппировкойМассив("Сумма(СуммаОборот)", "Контрагент")
Компоновщик макета сгенерирует для вывода следующее выражение:

СоединитьСтроки(Массив(Упорядочить(ВычислитьВыражениеСГруппировкойТаблицаЗначений("Представление(Сумма(НаборДанных.СуммаОборот)),Сумма(НаборДанных.СуммаОборот)","НаборДанных.Контрагент"),"2")))

Параметры:
<Выражение>
Тип: Строка. Выражение, которое нужно вычислить. Строка, например, Сумма(СуммаОборот).
<ВыражениеПолейГруппировки>
Тип: Строка. Выражения полей группировки – выражения полей группировки, перечисленные через запятую. Например, Контрагент, Партия.
<ОтборЗаписей>
Тип: Строка. Выражение, описывающее отбор, применяемый к детальным записям. В выражении не поддерживается использование агрегатных функций. Например,ПометкаУдаления = Ложь.
<ОтборГруппировок>
Тип: Строка. Выражение, описывающее отбор, применяемый к групповым записям. Например, Сумма(СуммаОборот) > &Параметр1.
Пример:

Максимум(ВычислитьВыражениеСГруппировкойМассив ("Сумма(СуммаОборот)", "Контрагент"));

Подробное описание синтаксиса функции можно найти по адресу http://its.1c.ru/db/v837doc#bookmark:dev:TI000000582
Теперь для расчета, продублируем поле «Заказать», с различными значениями «Рассчитывать по…», используя следующие выражения, обратите внимание, что в каждом выше стоящем уровне используются значения уровней ниже стоящих группировок.

В итоге получаем следующую конструкцию:

1С СКД: Суммирование значений на различных уровнях группировок

1С СКД: Суммирование значений на различных уровнях группировок


Предполагаю, что есть и другой способ расчета значений, на различных уровнях группировок в системе компоновки данными, при указанных условиях, если у вас есть данная информация, оставьте комментарий к данной заметке и она будет дополнена.

Программное добавление полей и ресурсов в СКД

Программное добавление полей и ресурсов в СКД

В данном примере будет показано, как осуществить программное добавление полей и ресурсов в СКД отчет, а так же, как передать таблицу значений в качества источника данных. Для примера реализации программного добавления полей в систему компоновки данных, будет использоваться таблица значений с неизвестным количеством колонок, которые нужно вывести в отчет СКД.
Для начала необходимо создать внешний отчет, в модуле объекта которого добавить процедуру ПриКомпоновкеРезультата:

1С программное добавление полей и ресурсов в СКД - СозданиеОтчета

1С программное добавление полей и ресурсов в СКД — СозданиеОтчета


В указанную процедуру добавим следующий код, в комментариях, описаны основные действия, сначала создается таблица значений со случайным количеством колонок, далее колонки, поля, ресурсы, программно добавляются в систему компоновки данными и передаются как внешний набор данных:

Процедура ПриКомпоновкеРезультата(ДокументРезультат, ДанныеРасшифровки, СтандартнаяОбработка)
	
	СтандартнаяОбработка = Ложь;
	
	//Структура внешних данных, для передачи в СКД
	ВнешниеНаборыДанных = Новый Структура; 
	
	тзДанные = Новый ТаблицаЗначений;
	
	тзДанные.Колонки.Добавить("Наименование", Новый ОписаниеТипов("Строка"));
	тзДанные.Колонки.Добавить("УникальноеНаименование", Новый ОписаниеТипов("Строка"));
	
	//С помощью генератора случайных чисел определяем количество колонок
	ГенераторСлучайныхЧисел = Новый ГенераторСлучайныхЧисел();
	
	СлучайноеЧисло = ГенераторСлучайныхЧисел.СлучайноеЧисло(1, 10);
	
	//Формируем колонки
	Для Индекс = 1 По СлучайноеЧисло Цикл
		тзДанные.Колонки.Добавить("Колонка" + Индекс, Новый ОписаниеТипов("Число"));
	КонецЦикла; 
	
	//Заполняем таблицу значений данными
	Для Индекс = 1 По 10 Цикл
		
		СтрокаТз = тзДанные.Добавить();
		
		СтрокаТз.Наименование			= "Начальная группировка";
		СтрокаТз.УникальноеНаименование = Новый УникальныйИдентификатор;
		
		Для Счетчик = 1 По СлучайноеЧисло Цикл
			
			ИмяКолонки = "Колонка" + Счетчик;
			СтрокаТз[ИмяКолонки] = ГенераторСлучайныхЧисел.СлучайноеЧисло(1, 10); 
			
		КонецЦикла; 
		
	КонецЦикла; 
	
	//Сохраняем таблицу значений в наборе внешних данных
	ВнешниеНаборыДанных.Вставить("тзДанные", тзДанные);
		
	//Получаем схему из макета
	СхемаКомпоновкиДанных = ПолучитьМакет("ОсновнаяСхемаКомпоновкиДанных");
	
	//Из схемы возьмем настройки
	Настройки = КомпоновщикНастроек.ПолучитьНастройки();
	
	//Программно добавляем поля и ресурсы
	Для Индекс = 1 По СлучайноеЧисло Цикл
		
		Поле = СхемаКомпоновкиДанных.НаборыДанных.НаборДанных1.Поля.Добавить(Тип("ПолеНабораДанныхСхемыКомпоновкиДанных"));
		
		Поле.Заголовок		= "Колонка" + Индекс;
		Поле.ПутьКДанным	= "Колонка" + Индекс;
		Поле.Поле			= "Колонка" + Индекс;
		Поле.ТипЗначения	= Новый ОписаниеТипов("Число",Новый КвалификаторыЧисла(15, 2)); 
		
		ПолеРесурса = СхемаКомпоновкиДанных.ПоляИтога.Добавить(); 
		
		ПолеРесурса.Выражение	= "СУММА(Колонка" +  Индекс + ")"; 
		ПолеРесурса.ПутьКДанным	= "Колонка" + Индекс; 
	
		ПолеРесурса.Группировки.Добавить("Наименование"); 
		ПолеРесурса.Группировки.Добавить("УникальноеНаименование"); 
		ПолеРесурса.Группировки.Добавить("ОбщийИтог"); 
		
	КонецЦикла;
	
	//Добавляем в выбранные поля
	Для Индекс = 1 По СлучайноеЧисло Цикл
		
		ВыбранноеПоле = Настройки.Выбор.Элементы.Добавить(Тип("ВыбранноеПолеКомпоновкиДанных"));
		
		ВыбранноеПоле.Заголовок		= "Колонка" + Индекс;
		ВыбранноеПоле.Использование	= Истина; 
		ВыбранноеПоле.Поле			= Новый ПолеКомпоновкиДанных("Колонка" + Индекс); 
		
	КонецЦикла;
	
	//Помещаем в переменную данные о расшифровке данных
	ДанныеРасшифровки = Новый ДанныеРасшифровкиКомпоновкиДанных;
	
	//Формируем макет, с помощью компоновщика макета
	КомпоновщикМакета = Новый КомпоновщикМакетаКомпоновкиДанных;
	
	//Передаем в макет компоновки схему, настройки и данные расшифровки
	МакетКомпоновки = КомпоновщикМакета.Выполнить(СхемаКомпоновкиДанных, Настройки, ДанныеРасшифровки);
	
	//Выполним компоновку с помощью процессора компоновки
	ПроцессорКомпоновкиДанных = Новый ПроцессорКомпоновкиДанных;
	//Передаем внешний набор данных
	ПроцессорКомпоновкиДанных.Инициализировать(МакетКомпоновки, ВнешниеНаборыДанных, ДанныеРасшифровки);
	
	//Очищаем поле табличного документа
	ДокументРезультат.Очистить();
	
	//Выводим результат в табличный документ
	ПроцессорВывода = Новый ПроцессорВыводаРезультатаКомпоновкиДанныхВТабличныйДокумент;
	ПроцессорВывода.УстановитьДокумент(ДокументРезультат);
	
	ПроцессорВывода.Вывести(ПроцессорКомпоновкиДанных);

КонецПроцедуры

После необходимо создать основную схему компоновки данных, как показано на изображении:

1С программное добавление полей и ресурсов в СКД - ВнешнийНаборДанных

1С программное добавление полей и ресурсов в СКД — ВнешнийНаборДанных


С простой настройкой группировки:
1С программное добавление полей и ресурсов в СКД - НастройкаГруппировки

1С программное добавление полей и ресурсов в СКД — НастройкаГруппировки


Сохранить внешний отчет и запустить в режиме 1С:Предприятие, несколько раз сформировать отчет, благодаря генератору случайных чисел, количество колонок практически всегда будет разным:
1С программное добавление полей и ресурсов в СКД - Итог

1С программное добавление полей и ресурсов в СКД — Итог


Тем самым было продемонстрировано, как программно добавить поле в систему компоновки данных.

Скачать рассмотренный в статье пример: ПрограммноеДобавлениеПолей

Интеграция 1С и Active Directory

Интеграция 1С и Active Directory

Изредка, в работе программистов и системных администраторов, возникают ситуации и задачи, когда необходимо произвести интеграцию 1С и Active Directory. В данном примере будет показано как с помощью технологии LDAP (англ. Lightweight Directory Access Protocol — «облегчённый протокол доступа к каталогам») и средств интеграции 1С, получить данные из Active Directory. Интеграция 1С и Active Directory может использоваться не только для получения данных, но и для создания объектов в структуре соответствующего домена.
В процессе создания алгоритма интеграции 1С и Active Directory, будет весьма полезна программа «Active Directory Explorer», создателем который является известный программист и писатель Марк Русси́нович. Данная программа позволит вам просмотреть дерево объектов выбранного вами домена, а если в начале запуска программы, сразу нажать кнопку «ОК», то домена по умолчанию, для текущего компьютера.

Active Directory Explorer Интеграция 1С и Active Directory

Интеграция 1С и Active Directory


Далее приведен код процедуры, с помощью которого можно получить список групп домена, в определенном организационном блоке (OU):

&НаКлиенте
Процедура ПолучитьГруппыДомена()
	
	КомандаАДО    = Новый COMОбъект("ADODB.Command");
	СоединениеАДО = Новый COMОбъект("ADODB.Connection");
	
	СоединениеАДО.Provider = "ADSDSOObject";
	Попытка
		СоединениеАДО.Open("Active Directory Provider");	
	Исключение
		Сообщить("Ошибка при открытии Active Directory Provider: " + ОписаниеОшибки());
		Возврат;
	КонецПопытки;
	
	КомандаАДО.ActiveConnection = СоединениеАДО;
	
	//Получаем имя домена к которому принадлежит данный компьютер 
	Попытка
		RootDSE = ПолучитьCOMОбъект("LDAP://RootDSE");
	Исключение
		Сообщить("Ошибка ПолучитьCOMОбъект(LDAP://RootDSE): " + ОписаниеОшибки());
		Возврат;
	КонецПопытки;
	
	ТекущийДомен = RootDSE.Get("defaultNamingContext");
	Сообщить("ТекущийДомен: " + ТекущийДомен);
	
	//Подключаемся к текущему домену
	Попытка
		ОбъектТекущегоДомена = ПолучитьCOMОбъект("LDAP://" + ТекущийДомен);	
	Исключение
		Сообщить("Ошибка ПолучитьCOMОбъект "+"LDAP://" + ТекущийДомен+": " + ОписаниеОшибки());
		Возврат;
	КонецПопытки;
	
	ИмяДомена = ОбъектТекущегоДомена.dc;
	Сообщить("ИмяДомена: " + ИмяДомена);
	
	//Формируем команду получения групп из блока Groups
	КомандаАДО.CommandText = "<LDAP://OU=Groups," + ТекущийДомен + ">" + ";(&(objectClass=top)(objectClass=organizationalUnit));name;onelevel";
	КомандаАДО.Properties("Page Size").Value     = 100;
	КомандаАДО.Properties("Timeout").Value       = 30;
	КомандаАДО.Properties("Cache Results").Value = Ложь;
	
	Попытка
		ВыборкаАДО = КомандаАДО.Execute();	
	Исключение
		Сообщить("Ошибка Execute(): " + ОписаниеОшибки());
		Возврат;
	КонецПопытки;
	
	//Выводим список групп
	Пока НЕ ВыборкаАДО.EOF Цикл
		
		Сообщить("Группа домена: " + ВыборкаАДО.Fields("name").Value);
		
		ВыборкаАДО.MoveNext();
		
	КонецЦикла;
	
	//Обязательно закрываем соединения и объекты
	ВыборкаАДО.Close();
	СоединениеАДО.Close();
	
КонецПроцедуры

Теперь получаем данные пользователей, которые включены в выбранную группу домена:

&НаКлиенте
Процедура ПолучитьПользователейГруппы()
	
	КомандаАДО    = Новый COMОбъект("ADODB.Command");
	СоединениеАДО = Новый COMОбъект("ADODB.Connection");
	
	СоединениеАДО.Provider = "ADSDSOObject";
	Попытка
		СоединениеАДО.Open("Active Directory Provider");	
	Исключение
		Сообщить("Ошибка при открытии Active Directory Provider: " + ОписаниеОшибки());
		Возврат;
	КонецПопытки;
	
	КомандаАДО.ActiveConnection = СоединениеАДО;
	
	Попытка
		RootDSE = ПолучитьCOMОбъект("LDAP://RootDSE");
	Исключение
		Сообщить("Ошибка ПолучитьCOMОбъект(LDAP://RootDSE): " + ОписаниеОшибки());
		Возврат;
	КонецПопытки;
	
	ТекущийДомен = RootDSE.Get("defaultNamingContext");
	Сообщить("ТекущийДомен: " + ТекущийДомен);
	
	Попытка
		ОбъектТекущегоДомена = ПолучитьCOMОбъект("LDAP://" + ТекущийДомен);	
	Исключение
		Сообщить("Ошибка ПолучитьCOMОбъект "+"LDAP://" + Объект.ТекущийДомен+": " + ОписаниеОшибки());
		Возврат;
	КонецПопытки;
	
	ИмяДомена = ОбъектТекущегоДомена.dc;
	Сообщить("ИмяДомена: " + ИмяДомена);
	
	
	КомандаАДО.CommandText = "<LDAP://OU=" + ГруппыДомена + ",OU=Groups," + Объект.ТекущийДомен + ">" + ";(&(objectCategory=person)(objectClass=user));sAMAccountName,userAccountControl,displayName,department,mail,telephoneNumber;onelevel";
	КомандаАДО.Properties("Page Size").Value     = 100;
	КомандаАДО.Properties("Timeout").Value       = 30;
	КомандаАДО.Properties("Cache Results").Value = Ложь;
	
	Попытка
		ВыборкаАДО = КомандаАДО.Execute();	
	Исключение
		Сообщить("Ошибка Execute(): " + ОписаниеОшибки());
		Возврат;
	КонецПопытки;
	
	Пока НЕ ВыборкаАДО.EOF Цикл
		
		ПользовательДомена = Новый Структура;
		
		Если ВыборкаАДО.Fields("userAccountControl").Value = 514 ИЛИ
			ВыборкаАДО.Fields("userAccountControl").Value = 546 ИЛИ
			ВыборкаАДО.Fields("userAccountControl").Value = 66050 Тогда
			 
			Сообщить("Заблокирован");
		Иначе
			Сообщить("НеЗаблокирован");
		КонецЕсли;
		
		Сообщить("ИмяПользователя " + СокрЛП(ВыборкаАДО.Fields("displayName").Value));
		Сообщить("ИмяАккаунта "     + СокрЛП(ВыборкаАДО.Fields("sAMAccountName").Value));
		Сообщить("Подразделение "   + СокрЛП(ВыборкаАДО.Fields("department").Value));
		Сообщить("Почта "           + СокрЛП(ВыборкаАДО.Fields("mail").Value));
		Сообщить("Телефон "         + СокрЛП(ВыборкаАДО.Fields("telephoneNumber").Value));
		
		ВыборкаАДО.MoveNext();
		
	КонецЦикла;
	
	ВыборкаАДО.Close();
	СоединениеАДО.Close();
	
КонецПроцедуры

По этому примеру можно создавать более сложные примеры интеграции 1С и Active Directory, более подробные сведения, вы можете получить по следующим адресам:
ADSI LDAP Provider
Использование протокола LDAP в скриптах

1с word шаблон — Заполнение таблиц в шаблоне Word

1с word шаблон — Заполнение таблиц в шаблоне Word

В предыдущей заметке «Использование шаблонов Word в 1С» был показан простой способ, как используя механизмы 1С и документа Word в качестве шаблона, можно создать печатную форму для вывода данных. В текущей заметке «1с word шаблон» будет показан один из способов, как можно реализовать заполнение таблиц в шаблоне Word.

Для примера использовался шаблон Word следующего вида:

1с word шаблон - Заполнение таблиц в шаблоне Word - Шаблон

1с word шаблон — Заполнение таблиц в шаблоне Word — Шаблон


Как видно из шаблона, закладка «Таблица1» является указателем на начало таблицы и служит для позиционирования выделения.
Теперь непосредственно сам способ, для его реализации использовалась внешняя обработка, в модуле формы которой, описана лишь одна процедура «ПриОткрытии(Отказ)»:

&НаКлиенте
Процедура ПриОткрытии(Отказ)
	
	//Попытка создать COM объект
	Попытка
		ОбъектВорд = Новый COMОбъект("Word.Application"); 
	Исключение
		Сообщить("Ошибка при запуске Microsoft Word: " + ОписаниеОшибки(), СтатусСообщения.Внимание);
	КонецПопытки;
	
	//Путь к шаблону
	ОбъектВорд.Documents.Add("C:\Users\Константин\Desktop\Шаблон.docx");
	ШаблонВорд = ОбъектВорд.ActiveDocument;
	
	//Заполняем первую таблицу
	Если ШаблонВорд.Bookmarks.Exists("Таблица1") Тогда
		
		//Выделяем обязательную закладку начала таблицы
		ШаблонВорд.Bookmarks("Таблица1").Select();
		
		
		//Перемещаемся вниз, выделяем строку таблицы и копируем ее в буфер обмена
		ШаблонВорд.Application.Selection.MoveDown();
		ШаблонВорд.Application.Selection.SelectRow();
		ШаблонВорд.Application.Selection.Copy();
		
		Для Счетчик = 1 По 10 Цикл
			
			//Заменяем значения
			ШаблонВорд.Application.Selection.Find.Execute("Номер" ,,,,,,,,,Счетчик,2);
			ШаблонВорд.Application.Selection.Find.Execute("ЗначениеКолонки1" ,,,,,,,,,Счетчик+10,2);
			//Последний параметр поиска пустой
			ШаблонВорд.Application.Selection.Find.Execute("ЗначениеКолонки2" ,,,,,,,,,Счетчик+100,);
			
			//Перемещаемся вниз, вставляем из буфера обмена строку
			ШаблонВорд.Application.Selection.MoveDown();
			ШаблонВорд.Application.Selection.Paste();
			//Перемещаемся вверх и выделяем строку для замены значений
			ШаблонВорд.Application.Selection.MoveUp();
			ШаблонВорд.Application.Selection.SelectRow();
			
		КонецЦикла;
		
		//Вырезаем лишнюю строку
		ШаблонВорд.Application.Selection.Cut();
		
		//Скрываем обязательную закладку начала таблицы
		ШаблонВорд.Bookmarks("Таблица1").Select();
		ШаблонВорд.Application.Selection.TypeText(" ");
		
	КонецЕсли;
	
	ОбъектВорд.Application.Visible = Истина;
	ОбъектВорд.Activate();
	
	//Закрытие документа
	//ОбъектВорд.Application.Quit();
	
КонецПроцедуры

Как видно из кода процедуры, сначала находим закладку, выделяем и копируем строку таблицы находящуюся ниже, после заменяем текст на значения и вставляем скопированную строку. Результат работы внешней обработки 1С «Заполнение таблиц в шаблоне Word»:

1с word шаблон - Заполнение таблиц в шаблоне Word - Результат

1с word шаблон — Заполнение таблиц в шаблоне Word — Результат

Скачать файл обработки 1С и шаблона Word.